PORTFOLIO_EX GetDayCandles;
DESCRIPTION Сохранение свечей графиков ряда параметров набора инструментов за текущую торговую сессию (в таблицу и в файл);
CLIENTS_LIST ALL_CLIENTS;
FIRMS_LIST ALL_FIRMS;
USE_CASE_SENSITIVE_CONSTANTS

PROGRAM

ClassCodeList = "SPBFUT"         ' коды классов бумаг, по которым будет осуществляться вывод
SecCodeList = "RIZ2"            ' коды бумаг, по которым будет осуществляться вывод
Params = ""            ' параметры, по которым будут строиться свечи 
GraphType = "PRICE"             ' тип графика
Intervals = "1,2,3,4,5,6,10,15,20,30,60"             ' интервал графика: 1 - минутный, 5 - 5-минутный и пр.
Separator = "."                  ' разделитель дробной части
OutPath = "c:\"                  ' путь к директории с файлом свечей
razn=3                        ' разница с Москвой в часах
start_time="10:00:00"            ' 10 часов 00 минут утра по Москве - время начала текущей торговой сессии "HHMMSS"


'=============================ФУНКЦИИ===============================
'ВЫЧИСЛЯЕТ ЧАСТНОЕ ОТ ДЕЛЕНИЯ
'DOUBLE div(DOUBLE Value, DOUBLE Value)
'Для работы нужны функции: никаких
func div(result,y_)
   result=FLOOR(result/y_)
end func

'ВЫЧИСЛЯЕТ ОСТАТОК ОТ ДЕЛЕНИЯ
'DOUBLE mod(DOUBLE Value, DOUBLE Value)
'Для работы нужны функции: никаких
func mod(result,y_)
   result=result-FLOOR(result/y_)*y_
end func

'ПРОВЕРЯЕМ ВХОЖДЕНИЕ pattern в СТРОКЕ list
'DOUBLE is_in_list(STRING Value, STRING Value)
'Для работы нужны функции: никаких
FUNC is_in_list(list, pattern)
  result = 0
  if  0 + find(list, 0, pattern) = -1 
    result = 0
  else
    result = 1
  end if
END FUNC

'ПЕРЕВОДИМ ВРЕМЯ ИЗ ФОРМАТА HHMMSS в HH:MM:SS
'STRING HHMMSS2Time(STRING Value)
'Для работы нужны функции: никаких
FUNC HHMMSS2Time(result)
 result=""&result
   if LEN(result)=5
    result="0"&result
   end if
 if LEN(result)=6
   result  = substr(result, 0, 2) & ":" & substr(result, 2, 2) & ":" & substr(result, 4, 2) 
 end if
END FUNC

'ПЕРЕВОДИМ ВРЕМЯ ИЗ ФОРМАТА HH:MM:SS в HHMMSS
'STRING Time2HHMMSS(STRING Value)
'Для работы нужны функции: FTEXT
Func Time2HHMMSS(result)
result=FTEXT(SUBSTR(result,0,FIND(result,0,":")))& _
      FTEXT(SUBSTR(result,FIND(result,0,":")+1,FIND(result,FIND(result,0,":")+1,":")-FIND(result,0,":")-1)) & _
      FTEXT(SUBSTR(result,FIND(result,FIND(result,0,":")+1,":")+1,len(result)-FIND(result,FIND(result,0,":")+1,":")-1))
result=FTEXT(result)
end Func

'ПРОВЕРЯЕМ КОРРЕКТНОСТЬ КОЛИЧЕСТВА СИМОЛОВ ПЕРЕМЕННОЙ
'STRING FTEXT(STRING Value)
'Для работы нужны функции: никаких
func FTEXT(result)
result=""&result
   if (len(result)=1) OR (len(result)=5)
    result="0"&result
   end if
end func

'ЗАМЕНЯЕМ 0 ПУСТОЙ СТРОКОЙ
'STRING REPLACE_0(STRING Value)
'Для работы нужны функции: никаких
func REPLACE_0(result)
   if result+0=0
    result=""
   end if
end func

'ПЕРЕВОДИМ НОРМАЛЬНОЕ ВРЕМЯ HHMMSS В СЕКУНДЫ
'DOUBLE Time2Sec(STRING Value)
'Для работы нужны функции: Time2HHMMSS, FTEXT
func Time2Sec(result)
result=Time2HHMMSS(result)
   result=SUBSTR(result,0,2)*3600+SUBSTR(result,2,2)*60+SUBSTR(result,4,2)
end func

'ПАУЗА В СЕКУНДАХ
'DOUBLE Sleep(DOUBLE Value)
'Для работы нужны функции: никаких
func Sleep(result)
   time_begin = get_value(GET_DATETIME(), "HOUR")*3600+get_value(GET_DATETIME(), "HOUR")*60+get_value(GET_DATETIME(), "SEC")
   for i_ from 0 to 2
      if (get_value(GET_DATETIME(), "HOUR")*3600+get_value(GET_DATETIME(), "HOUR")*60+get_value(GET_DATETIME(), "SEC") - time_begin) >= result
         BREAK
      end if
      i_=i_-1
   end for
end func

'ПЕРЕВОДИМ СЕКУНДЫ В НОРМАЛЬНОЕ ВРЕМЯ HH:MM:SS
'STRING Sec2Time(DOUBLE Value)
'Для работы нужны функции: FTEXT, HHMMSS2Time
func Sec2Time(result)
result=FTEXT(floor(result/3600))& _
      FTEXT(floor((result-(floor(result/3600))*3600)/60))& _
      FTEXT((result-(floor(result/3600))*3600)-(floor((result-(floor(result/3600))*3600)/60)) * 60)
result=HHMMSS2Time(result)
end func 

'ПЕРЕВОДИТ ДАТУ В ФОРМАТЕ YYYYMMDD или DD.MM.YYYY В КОЛИЧЕСТВО ДНЕЙ НАЧИНАЯ С 1970.01.01
'DOUBLE date2day(STRING Value)
'Для работы нужны функции: никаких
func date2day(YYYYMMDD_)
   if (SUBSTR (YYYYMMDD_, 2, 1)=",") or (SUBSTR (YYYYMMDD_, 2, 1)=".")
      YYYYMMDD_=SUBSTR(YYYYMMDD_,6,4)&SUBSTR(YYYYMMDD_,3,2)&SUBSTR(YYYYMMDD_,0,2)
   end if
   result=SUBSTR(YYYYMMDD_,0,4)*365+floor((SUBSTR(YYYYMMDD_,0,4)-1)/4)-719542
   result=result+substr("031059090120151181212243273304334365",SUBSTR(YYYYMMDD_,4,2)*3-6,3)
   if (SUBSTR(YYYYMMDD_,0,4)-floor(SUBSTR(YYYYMMDD_,0,4)/4)*4=0) AND (SUBSTR(YYYYMMDD_,4,2)+0>2)
      result=result+1
   end if
result=(result+SUBSTR(YYYYMMDD_,6,2)-1)
end func

'ПЕРЕВОДИМ МАССИВ get_datetime() В НОРМАЛЬНОЕ ВРЕМЯ HHMMSS
'STRING Map2HHMMSS(MAP  Name)
'Для работы нужны функции: FTEXT 
FUNC Map2HHMMSS(result)
result=FTEXT(get_value(result, "HOUR"))& _
   FTEXT(get_value(result, "MIN"))& _
   FTEXT(get_value(result, "SEC"))
END FUNC

'ВЫВОДИТ ИЗ МАССИВА get_datetime() ИЛИ get_trade_date() ДАТУ В ФОРМАТЕ YYYYMMDD
'STRING Map2YYYYMMDD(MAP  Name)
'Для работы нужны функции: FTEXT 
FUNC Map2YYYYMMDD(result)
result=FTEXT(get_value(result, "YEAR"))& _
   FTEXT(get_value(result, "MONTH"))& _
   FTEXT(get_value(result, "DAY"))
END FUNC

'ПЕРЕВОДИТ ДАТУ В ФОРМАТЕ YYYYMMDD В ФОРМАТ DD.MM.YYYY
'STRING Map2YYYYMMDD(STRING Value)
'Для работы нужны функции: FTEXT 
FUNC YYYYMMDD2Date(result)
   result=SUBSTR(result,6,2)&"."&SUBSTR(result,4,2)&"."&SUBSTR(result,0,4)
END FUNC

'УСТРАНЯЕТ В get_datetime() РАЗНИЦУ ВО ВРЕМЕНИ
'MAP Fix_get_datetime(MAP  Name, DOUBLE Value)
'Для работы нужны функции: FTEXT
FUNC Fix_get_datetime(result, time_zone)
if get_value(result, "HOUR")+0>=time_zone+0
   result=SET_VALUE(result, "HOUR",(get_value(result, "HOUR")-time_zone))
   result=SET_VALUE(result, "DATETIME",SUBSTR(get_value(result, "DATETIME"),0,11)& _
         FTEXT(SUBSTR(get_value(result, "DATETIME"),11,2)-time_zone)& _
         SUBSTR(get_value(result, "DATETIME"),13,10))   
end if
END FUNC

'ЗАМЕНА РАЗДЕЛИТЕЛЯ ДРОБНОЙ ЧАСТИ
'STRING replace_decimal_symbol(STRING Value, STRING Value)
'Для работы нужны функции: никаких
func replace_decimal_symbol(string, dchar)
   result=""
   string=""&string
      for rdc_x from 0 to len(string)-1
            if (substr(string, rdc_x, 1) = ".") OR (substr(string, rdc_x, 1)=",")
               result=result & dchar
            else
               result=result & substr(string, rdc_x, 1)
            end if
      end for
end func

'ЗАМЕНА В СТРОКЕ string ОДНОГО СИМВОЛА dchar_in ДРУГИМ dchar_out
'STRING replace_symbol(STRING Value, STRING Value, STRING Value)
'Для работы нужны функции: никаких 
func replace_symbol(string, dchar_in, dchar_out)
   result=""
   string=""&string
      for rdc_x from 0 to len(string)-1
            if substr(string, rdc_x, 1) = dchar_in
               result=result & dchar_out
            else
               result=result & substr(string, rdc_x, 1)
            end if
      end for
end func

'=============================ФУНКЦИИ===============================

NEW_GLOBAL("Counter", 1)         ' счетчик записей в массив выходных данных (таблицы)
NEW_GLOBAL("Date", "0")            ' дата текущей торговой сессии QUIK
NEW_GLOBAL("CommonTime", time2sec(start_time))    
NEW_GLOBAL("OutFile", "")

if Date = "0"
   Date = Map2YYYYMMDD(GET_TRADE_DATE())   ' Преобразовали текущую дату в принятый для вызова GET_CANDLE формат
    OutFile = OutPath & YYYYMMDD2Date(Date) & ".txt" ' Сформировали имя файла данных со свечами
    CLEAR_FILE(OutFile) 'Очистили файл 
   WRITELN(OutFile, "<TICKER>,<PER>,<DATE>,<TIME>,<OPEN>,<HIGH>,<LOW>,<CLOSE>,<VOL>") ' Вывели заголовок
   DELETE_ALL_ITEMS()
   CurIntervals = CREATE_MAP() ' Создаем массив счетчиков интервалов
   CurIntervals = SET_VALUE(CurIntervals, "1", 1)
   CurIntervals = SET_VALUE(CurIntervals, "2", 0)
   CurIntervals = SET_VALUE(CurIntervals, "3", 0)
   CurIntervals = SET_VALUE(CurIntervals, "4", 0)
   CurIntervals = SET_VALUE(CurIntervals, "5", 0)
   CurIntervals = SET_VALUE(CurIntervals, "6", 0)
   CurIntervals = SET_VALUE(CurIntervals, "10", 0)
   CurIntervals = SET_VALUE(CurIntervals, "15", 0)
   CurIntervals = SET_VALUE(CurIntervals, "20", 0)
   CurIntervals = SET_VALUE(CurIntervals, "30", 0)
   CurIntervals = SET_VALUE(CurIntervals, "60", 0)
end if

CurTime = Fix_get_datetime(GET_DATETIME(),razn)
CurTimeInSec = time2sec(Map2HHMMSS(CurTime)) ' Преобразовали текущее время в количество секунд
'CurTimeInSec = time2sec(GET_INFO_PARAM("SERVERTIME"))

if (CurTimeInSec - CommonTime) >= 60 ' Текущее время более 10.00 (время московское) и с момента последнего опроса данных прошло не менее минуты
   for i from 0 to floor((CurTimeInSec - CommonTime)/ 60)
      for Interval in Intervals
         CurInterval = GET_VALUE(CurIntervals, Interval)
         if (0 + CurInterval) = (0 + Interval)
            if (0 + Interval) <> 1
               CurTime = sec2time(CommonTime - CurInterval * 60)
            else
               CurTime = sec2time(CommonTime)
            end if
            for ClassCode in ClassCodeList
               for SecCode in SecCodeList
                  if LEN(Params)=0
                     Params=" "
                  END IF
                   for Param in Params
                     Candle = GET_CANDLE(ClassCode, SecCode, Param, Interval, GraphType, Date, Time2HHMMSS(CurTime))
                     Open = replace_decimal_symbol(GET_VALUE(Candle, "OPEN"),Separator)
                     if Open+0 <> 0 ' Если цена открытия интервала равна нулю, свечу не выводим
                        Close = replace_decimal_symbol(GET_VALUE(Candle, "Close"),Separator)
                        High = replace_decimal_symbol(GET_VALUE(Candle, "High"),Separator)
                        Low = replace_decimal_symbol(GET_VALUE(Candle, "Low"),Separator)
                        Volume = replace_decimal_symbol(GET_VALUE(Candle, "Volume"),Separator)
                        Candle = SET_VALUE(Candle, "Security", SecCode)
                        Candle = SET_VALUE(Candle, "ClassCode", ClassCode)
                        Candle = SET_VALUE(Candle, "Param", Param)
                        Candle = SET_VALUE(Candle, "Date", YYYYMMDD2Date(Date))
                        Candle = SET_VALUE(Candle, "Time", CurTime)
                        Candle = SET_VALUE(Candle, "Interval", Interval)
                         ADD_ITEM(Counter, Candle)
                           WRITELN(OutFile, SecCode  & " [" & ClassCode & "]," & Interval & "," & Date  & "," & Time2HHMMSS(CurTime) & "," & Open & "," & High & "," & Low & "," & Close & "," & Volume)         
                        'Counter = Counter + 1
                     end if
                  end for
                  
               end for
            end for
            CurIntervals = SET_VALUE(CurIntervals, Interval, 1) ' скинули интервальный счетчик
         else
            CurIntervals = SET_VALUE(CurIntervals, Interval, (CurInterval + 1)) ' накинули интервальный счетчик
         end if
      end for
      CommonTime = CommonTime + 60 ' накинули время
   end for
end if

END_PROGRAM

PARAMETER Security;
PARAMETER_TITLE Код инструмента;
PARAMETER_DESCRIPTION Код инструмента;
PARAMETER_TYPE String(12);
END

PARAMETER ClassCode;
PARAMETER_TITLE Код класса;
PARAMETER_DESCRIPTION Код класса;
PARAMETER_TYPE String(12);
END

PARAMETER Param;
PARAMETER_TITLE Параметр;
PARAMETER_DESCRIPTION Параметр;
PARAMETER_TYPE String(12);
END

PARAMETER Date;
PARAMETER_TITLE Дата;
PARAMETER_DESCRIPTION Дата интервала;
PARAMETER_TYPE String(10);
END

PARAMETER Time;
PARAMETER_TITLE Время;
PARAMETER_DESCRIPTION Время интервала;
PARAMETER_TYPE String(10);
END

PARAMETER Interval;
PARAMETER_TITLE Интервал;
PARAMETER_DESCRIPTION Интервал;
PARAMETER_TYPE String(2);
END

PARAMETER Open;
PARAMETER_TITLE Открытие;
PARAMETER_DESCRIPTION Цена открытия интервала;
PARAMETER_TYPE Numeric(20,4);
END

PARAMETER Close;
PARAMETER_TITLE Закрытие;
PARAMETER_DESCRIPTION Цена закрытия интервала;
PARAMETER_TYPE Numeric(20,4);
END

PARAMETER High;
PARAMETER_TITLE Максимум;
PARAMETER_DESCRIPTION Максимальная цена интервала;
PARAMETER_TYPE Numeric(20,4);
END

PARAMETER Low;
PARAMETER_TITLE Минимум;
PARAMETER_DESCRIPTION Минимальная цена интервала;
PARAMETER_TYPE Numeric(20,4);
END

PARAMETER Volume;
PARAMETER_TITLE Объем;
PARAMETER_DESCRIPTION Суммарный объем сделок в интервале;
PARAMETER_TYPE Numeric(20,4);
END

END_PORTFOLIO_EX