Проблема с DELETE_ALL_ITEMS()

PORTFOLIO_EX SaveTrades;
DESCRIPTION SaveTrades;
CLIENTS_LIST ALL_CLIENTS;
FIRMS_LIST ALL_FIRMS;
USE_CASE_SENSITIVE_CONSTANTS;
PROGRAM
NEW_GLOBAL("NUM_OF_TRADES",0)
NEW_GLOBAL("ii",380)
OUT_PATH="C:\quik_open\robots\trades\"
SERVERTIME=GET_INFO_PARAM("SERVERTIME")
SERVERTIME=get_servertime(SERVERTIME)+0
td=GET_TRADEDATE()
cd=GET_DATE()
if (SERVERTIME<100000)OR(SERVERTIME>235500)OR(td<>cd)
  return()
end if
CTIME = GET_DATETIME()
   CYEAR = GET_VALUE(CTIME, "YEAR")
   CMONTH = GET_VALUE(CTIME, "MONTH")
   CDAY = GET_VALUE(CTIME, "DAY")
   OUT_FILE= OUT_PATH & CYEAR & "." & PAD(CMONTH,2) & "." & PAD(CDAY,2) & ".txt"
NEW_NUM_OF_TRADES=GET_NUMBER_OF("TRADES")+0
if NEW_NUM_OF_TRADES+0>NUM_OF_TRADES+0
   if NUM_OF_TRADES=0
      CLEAR_FILE(OUT_FILE)
   end if
   FOR i FROM NUM_OF_TRADES+1 to NEW_NUM_OF_TRADES
      TRADE = GET_ITEM ("TRADES", i)
      if (GET_VALUE(TRADE,"DATE")+0==td)
         ii=ii+1
            if GET_VALUE(TRADE,"OPERATION")&""="SELL"
               OPERATION="Продажа"
            else
               OPERATION="Купля"
            end if
            S=ii & ";" & GET_VALUE(TRADE,"SECCODE") & ";" & OPERATION & ";" & GET_VALUE(TRADE,"PRICE") & ";" & GET_VALUE(TRADE,"QUANTITY") & ";" & GET_VALUE(TRADE,"TIME") & ";" & GET_VALUE(TRADE,"NUMBER") & ";" & GET_VALUE(TRADE,"TS_COMISSION") & ";" & GET_VALUE(TRADE,"COMMENT")& ";" & GET_VALUE(TRADE,"ACCOUNT")
            WRITELN(OUT_FILE, S)
            delete_all_items()
            ADD_ROW("Сохранена сделка",i)
      end if
   end for
   NUM_OF_TRADES=NEW_NUM_OF_TRADES+0
      strfile=GET_FILE_LEN(OUT_FILE)+0
      delete_all_items()
      ADD_ROW("Строк в файле",strfile)
      ADD_ROW("Trade date",td)
      ADD_ROW("Curr date",cd)
      if strfile<ii
         NUM_OF_TRADES=0
         ii=0
      end if
end if


FUNC PAD(number, length)
   RESULT = number
   IF LEN(number) < length
     c123 = 1
     FOR c123 FROM 1 TO (length - LEN(number))
      RESULT = "0" & RESULT
     END FOR
   END IF
END FUNC

FUNC ADD_ROW(PRM, VAL)
  M = CREATE_MAP()
  M = SET_VALUE(M, "Param", PRM)
  M = SET_VALUE(M, "Value", VAL)
  ADD_ITEM(GET_NUMBER_OF("OWN") + 1, M)
END FUNC



FUNC GET_TRADEDATE()
  RESULT = GET_VALUE(GET_TRADE_DATE (),"YEAR")*10000+GET_VALUE(GET_TRADE_DATE (),"MONTH")*100+GET_VALUE(GET_TRADE_DATE (),"DAY")+0
end FUNC

FUNC GET_DATE()
  RESULT = GET_VALUE(GET_DATETIME (),"YEAR")*10000+GET_VALUE(GET_DATETIME (),"MONTH")*100+GET_VALUE(GET_DATETIME (),"DAY")+0
end FUNC

func get_servertime(_st)
    c1=FIND(_st,0,":")
    c2=FIND(_st,c1+1,":")
  RESULT=substr(_st,0,c1)&substr(_st,c1+1,c2-c1-1)&substr(_st,c2+1,2)
end func

END_PROGRAM

PARAMETER Param;
PARAMETER_TITLE Параметр;
PARAMETER_DESCRIPTION Название параметра;
PARAMETER_TYPE STRING(64);
END

PARAMETER Value;
PARAMETER_TITLE Значение;
PARAMETER_DESCRIPTION Значение параметра;
PARAMETER_TYPE STRING(20);
END

END_PORTFOLIO_EX